lessen

Bezoek een msx-beurs, of een lokale msx-meeting. Daar zijn meestal wel boekjes te koop uit de jaren 80, dat was een beetje die tijd zegmaar.

Eerstvolgende grote beurs is in't najaar in Bussum, lokale msx-meeting is afhankelijk van waar je woont.

Uiteraard is MRC (of een van de andere msx-sites waar een forum is) ook een grote bron van antwoorden!

(kortom: stel je vragen!)

Nou, om maar met het makkelijkste te beginnen: er bestaat niet zoiets als een 'input box'. Iets in de trant van je omschrijving zou dit kunnen zijn:

10 CLS: LINE INPUT "Voer je naam in:",A$
20 PRINT "Hoi ";A$

Het eerste commando (CLS) maakt je scherm mooi leeg, behalve misschien de onderste regel. Die kun je wegkrijgen met een KEY OFF commando. Voorts wacht het LINE INPUT statement op een textuele invoer, beëindigd met een RETURN. Het zojuist getypte komt in A$ te staan die later met een PRINT op het scherm komt. Veel plezier met aanklooien!

Zoals in windows kan maar dan moet je dat grafisch oplossen in bijvoorbeeld screen 2.
Met: open "grp:" for output #1
kun je tekst naar grafische schermen afdrukken. Toetsen afvangen kun je met inkey$, ook de back space (char code 8).
Kijk eens of je 2e hands MSX Basic boek kunt vinden.

Best wel leuk weer eens wat in MSX basic te doen.
Ik zit nu meer in Pascal. Ik kon het niet laten:

10 SCREEN 5
20 COLOR 1
30 OPEN "grp:" FOR OUTPUT AS#1
40 PSET(19,9):PRINT#1,"Enter your name:"
50 REM *** This is the input box ***
60 LINE (19,19)-(181,29),14,BF
70 LINE (18,18)-(182,18),1
80 LINE -(182,30),15
90 LINE -(18,30),15
100 LINE -(18,18),1
110 COLOR ,14
120 REM *** This is the actual input routine ***
130 REM *** only a-z and A-Z are allowed     ***
140 P% = 12
150 K$ = INKEY$: IF K$="" THEN GOTO 150
160 IF ASC(K$) >=65 AND ASC(K$) <=122 AND P% <170 THEN P%=P%+8: PSET(P%, 20),14:PRINT#1, K$: W$=W$+K$
170 REM *** BACK SPACE ***
180 IF ASC(K$) = 8 AND P%>12 THEN LINE (P%,20)-(P%+8,28),14,BF: W$=LEFT$(W$, LEN(W$)-1): P%=P%-8
190 REM *** ENTER PRESSED ***
200 IF ASC(K$) = 13 THEN GOTO 220
210 GOTO 150
220 COLOR ,4
230 PSET (19,40): PRINT#1, "You entered: "+W$
240 CLOSE#1
250 IF INKEY$="" THEN GOTO 250
260 COLOR 15,4,4

Best wel leuk weer eens wat in MSX basic te doen.
Ik zit nu meer in Pascal. Ik kon het niet laten:

10 SCREEN 5
20 COLOR 1
30 OPEN "grp:" FOR OUTPUT AS#1
40 PSET(19,9):PRINT#1,"Enter your name:"
50 REM *** This is the input box ***
60 LINE (19,19)-(181,29),14,BF
70 LINE (18,18)-(182,18),1
80 LINE -(182,30),15
90 LINE -(18,30),15
100 LINE -(18,18),1
110 COLOR ,14
120 REM *** This is the actual input routine ***
130 REM *** only a-z and A-Z are allowed     ***
140 P% = 12
150 K$ = INKEY$: IF K$="" THEN GOTO 150
160 IF ASC(K$) >=65 AND ASC(K$) <=122 AND P% <170 THEN P%=P%+8: PSET(P%, 20),14:PRINT#1, K$: W$=W$+K$
170 REM *** BACK SPACE ***
180 IF ASC(K$) = 8 AND P%>12 THEN LINE (P%,20)-(P%+8,28),14,BF: W$=LEFT$(W$, LEN(W$)-1): P%=P%-8
190 REM *** ENTER PRESSED ***
200 IF ASC(K$) = 13 THEN GOTO 220
210 GOTO 150
220 COLOR ,4
230 PSET (19,40): PRINT#1, "You entered: "+W$
240 CLOSE#1
250 IF INKEY$="" THEN GOTO 250
260 COLOR 15,4,4

Nu nog de cursor-toetsen en een 'cancel' (ESC) optie erbij en de inputbox is klaar
Verder zou ik de volgende regels als volgt schrijven:

150 K$=INPUT$(1)
200 IF ASC(K$)<>13 THEN 150
210 '
250 K$=INPUT$(1)